lua-openssl/CMakeLists.txt at master · OneLuaPro/lua-openssl · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
cmake_minimum_required(VERSION 3.31)
project(lua-openssl C)

set(CMAKE_MACOSX_RPATH 1)
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH}
                      "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules")
option(BUILD_SHARED_LUA_OPENSSL "Shared or Static lua-openssl" ON)
option(BUILD_LINK_LUA_LIBRARIES "Link Lua libraries during build-time" OFF)
if(WIN32)
  set(BUILD_LINK_LUA_LIBRARIES ON)
endif()

include(GNUInstallDirs)

find_package(LuaJIT)
if(NOT LUAJIT_FOUND)
  # try to find OneLuaPro Lua libs and headers first. cmake v3.31 does not
  # know about Lua 5.5 unfortunately
  find_package(liblua CONFIG HINTS ${LUA_HINTS})
  if(liblua_FOUND)
    message(STATUS "liblua version        : ${liblua_VERSION}")
    message(STATUS "liblua install prefix : ${LIBLUA_INSTALLDIR}")
    message(STATUS "liblua include dir    : ${LIBLUA_INCLUDEDIR}")
    message(STATUS "liblua lib dir        : ${LIBLUA_LIBDIR}")
    set(LUA_LIBRARIES ${LIBLUA_LIBDIR}/liblua.lib)
    set(LUA_VERSION_MAJOR ${liblua_VERSION_MAJOR})
    set(LUA_VERSION_MINOR ${liblua_VERSION_MINOR})
  else()
    # fallback
    find_package(Lua REQUIRED)
  endif()
endif()
find_package(OpenSSL REQUIRED)

set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
set(THREADS_PREFER_PTHREAD_FLAG TRUE)
find_package(Threads REQUIRED)

if(BUILD_SHARED_LUA_OPENSSL)
  set(LUA_OPENSSL_LIBTYPE MODULE)
  if(WIN32)
    add_definitions(-DLUA_BUILD_AS_DLL)
    if(MSVC)
      add_compile_definitions(
	WIN32_LEAN_AND_MEAN
	_CRT_SECURE_NO_WARNINGS
	_CRT_NONSTDC_NO_DEPRECATE
	ssize_t=SSIZE_T
	OPENSSL_SYS_WIN32
      )
      if(CMAKE_C_COMPILER_ID MATCHES "MSVC")
	add_compile_options(/Zc:preprocessor /wd5105 /wd4113 /wd4267 /wd4244 /wd4018)
      else()
	add_compile_options(-Wno-unused-command-line-argument -Wno-comment)
      endif()
    endif()
    set(EXTRA_LIBS "ws2_32.lib" "crypt32.lib" "bcrypt.lib")
  endif()
else()
  set(LUA_OPENSSL_LIBTYPE STATIC)
endif()

add_library(lua-openssl ${LUA_OPENSSL_LIBTYPE}
  deps/auxiliar/auxiliar.c
  deps/auxiliar/subsidiar.c
  src/asn1.c
  src/bio.c
  src/callback.c
  src/cipher.c
  src/cms.c
  src/compat.c
  src/crl.c
  src/csr.c
  src/dh.c
  src/digest.c
  src/dsa.c
  src/ec.c
  src/engine.c
  src/mac.c
  src/hmac.c
  src/kdf.c
  src/lbn.c
  src/lhash.c
  src/misc.c
  src/ocsp.c
  src/oids.txt
  src/openssl.c
  src/ots.c
  src/param.c
  src/pkcs12.c
  src/pkcs7.c
  src/pkey.c
  src/private.h
  src/provider.c
  src/rsa.c
  src/sk.h
  src/srp.c
  src/ssl.c
  src/th-lock.c
  src/util.c
  src/x509.c
  src/xattrs.c
  src/xexts.c
  src/xname.c
  src/xalgor.c
  src/xstore.c)

target_include_directories(
  lua-openssl PUBLIC ${OPENSSL_INCLUDE_DIR} ${LUA_INCLUDE_DIR} deps
                     deps/lua-compat/c-api deps/auxiliar)

target_link_libraries(lua-openssl PUBLIC ${OPENSSL_LIBRARIES} ${EXTRA_LIBS}
                                         Threads::Threads)

if(BUILD_LINK_LUA_LIBRARIES)
  target_link_libraries(lua-openssl PUBLIC ${LUA_LIBRARIES})
  if(UNIX)
    target_link_options(lua-openssl PUBLIC -Wl,--no-undefined)
  endif()
else()
  if(APPLE)
    target_link_options(lua-openssl PUBLIC -bundle -undefined dynamic_lookup)
  endif()
endif()

target_compile_options(lua-openssl PRIVATE -DLUA_LIB)

set_target_properties(lua-openssl PROPERTIES PREFIX "" OUTPUT_NAME "openssl")

install(
  TARGETS lua-openssl
  LIBRARY
  DESTINATION
  ${CMAKE_INSTALL_LIBDIR}/lua/${LUA_VERSION_MAJOR}.${LUA_VERSION_MINOR}
)