SyntaxTutor/SyntaxTutor.pro at main · jose-rZM/SyntaxTutor · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
QT       += core gui printsupport svg
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TRANSLATIONS += translations/st_es.ts \
                translations/st_en.ts

CONFIG += c++20

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

INCLUDEPATH += \
    $$PWD/src \
    $$PWD/src/app \
    $$PWD/src/gui \
    $$PWD/src/widgets \
    $$PWD/src/backend

SOURCES += \
    src/backend/grammar.cpp \
    src/backend/grammar_factory.cpp \
    src/backend/ll1_parser.cpp \
    src/backend/lr0_item.cpp \
    src/backend/slr1_parser.cpp \
    src/backend/symbol_table.cpp \
    src/widgets/customtextedit.cpp \
    src/gui/lltabledialog.cpp \
    src/gui/lltutorwindow.cpp \
    src/app/main.cpp \
    src/gui/mainwindow.cpp \
    src/gui/slrtabledialog.cpp \
    src/gui/slrtutorwindow.cpp \
    src/widgets/tutorialmanager.cpp

HEADERS += \
    src/gui/UniqueQueue.h \
    src/appversion.h \
    src/backend/grammar.hpp \
    src/backend/grammar_factory.hpp \
    src/backend/ll1_parser.hpp \
    src/backend/lr0_item.hpp \
    src/backend/slr1_parser.hpp \
    src/backend/state.hpp \
    src/backend/symbol_table.hpp \
    src/widgets/customtextedit.h \
    src/gui/lltabledialog.h \
    src/gui/lltutorwindow.h \
    src/gui/mainwindow.h \
    src/gui/slrtabledialog.h \
    src/gui/slrtutorwindow.h \
    src/gui/slrwizard.h \
    src/gui/slrwizardpage.h \
    src/widgets/tutorialmanager.h

FORMS += \
    src/gui/lltutorwindow.ui \
    src/gui/mainwindow.ui \
    src/gui/slrtutorwindow.ui

win32:CONFIG(release, debug|release) {
    msvc {
        QMAKE_CXXFLAGS_RELEASE += /O2 /GL /DNDEBUG
        QMAKE_LFLAGS_RELEASE   += /LTCG
    }

    !msvc {
        QMAKE_CXXFLAGS_RELEASE += -O3 -flto -DNDEBUG -pipe
        QMAKE_LFLAGS_RELEASE   += -s -flto
    }
}

unix:!mac:CONFIG(release, debug|release) {
    QMAKE_CXXFLAGS_RELEASE += \
        -O3 \
        -flto \
        -DNDEBUG \
        -fvisibility=hidden \
        -fvisibility-inlines-hidden \
        -pipe

    QMAKE_LFLAGS_RELEASE += \
        -flto \
        -s \
        -Wl,--as-needed

    # Tras link: strippear de nuevo por si quedan símbolos
    QMAKE_POST_LINK += $$QMAKE_STRIP ./$${TARGET}
}

macx {
    CONFIG += app_bundle
    QMAKE_MACOS_DEPLOYMENT_TARGET = 10.15
    QMAKE_CXXFLAGS_RELEASE = -O3 -DNDEBUG
}

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target

RESOURCES += \
    resources.qrc