feat(ascii): implement f() to validate string as number according to JSON specification (#31)

* fix(ascii): implement isStringNumeric according to JSON specification

* docs

* fix: implement as new function

Author: Duologic

ascii.libsonnet

@@ -32,4 +32,68 @@ local d = import 'github.com/jsonnet-libs/docsonnet/doc-util/main.libsonnet';
     [d.arg('str', d.T.string)]
   ),
   isStringNumeric(str): std.all(std.map(self.isNumber, std.stringChars(str))),
+
+  '#isStringJSONNumeric':: d.fn(
+    '`isStringJSONNumeric` reports whether string `s` is a number as defined by [JSON](https://www.json.org/json-en.html).',
+    [d.arg('str', d.T.string)]
+  ),
+  isStringJSONNumeric(str):
+    //                           "1"            "9"
+    local onenine(c) = (cp(c) >= 49 && cp(c) <= 57);
+
+    //                         "0"
+    local digit(c) = (cp(c) == 48 || onenine(c));
+
+    local digits(str) =
+      std.length(str) > 0
+      && std.all(
+        std.foldl(
+          function(acc, c)
+            acc + [digit(c)],
+          std.stringChars(str),
+          [],
+        )
+      );
+
+    local fraction(str) = str == '' || (str[0] == '.' && digits(str[1:]));
+
+    local sign(c) = (c == '-' || c == '+');
+
+    local exponent(str) =
+      str == ''
+      || (str[0] == 'E' && digits(str[1:]))
+      || (str[0] == 'e' && digits(str[1:]))
+      || (std.length(str) > 1 && str[0] == 'E' && sign(str[1]) && digits(str[2:]))
+      || (std.length(str) > 1 && str[0] == 'e' && sign(str[1]) && digits(str[2:]));
+
+
+    local integer(str) =
+      (std.length(str) == 1 && digit(str[0]))
+      || (std.length(str) > 0 && onenine(str[0]) && digits(str[1:]))
+      || (std.length(str) > 1 && str[0] == '-' && digit(str[1]))
+      || (std.length(str) > 1 && str[0] == '-' && onenine(str[1]) && digits(str[2:]));
+
+    local expectInteger =
+      if std.member(str, '.')
+      then std.split(str, '.')[0]
+      else if std.member(str, 'e')
+      then std.split(str, 'e')[0]
+      else if std.member(str, 'E')
+      then std.split(str, 'E')[0]
+      else str;
+
+    local expectFraction =
+      if std.member(str, 'e')
+      then std.split(str[std.length(expectInteger):], 'e')[0]
+      else if std.member(str, 'E')
+      then std.split(str[std.length(expectInteger):], 'E')[0]
+      else str[std.length(expectInteger):];
+
+    local expectExponent = str[std.length(expectInteger) + std.length(expectFraction):];
+
+    std.all([
+      integer(expectInteger),
+      fraction(expectFraction),
+      exponent(expectExponent),
+    ]),
 }

docs/ascii.md

@@ -14,6 +14,7 @@ local ascii = import "github.com/jsonnet-libs/xtd/ascii.libsonnet"
 
 * [`fn isLower(c)`](#fn-islower)
 * [`fn isNumber(c)`](#fn-isnumber)
+* [`fn isStringJSONNumeric(str)`](#fn-isstringjsonnumeric)
 * [`fn isStringNumeric(str)`](#fn-isstringnumeric)
 * [`fn isUpper(c)`](#fn-isupper)
 
@@ -35,6 +36,14 @@ isNumber(c)
 
 `isNumber` reports whether character `c` is a number.
 
+### fn isStringJSONNumeric
+
+```ts
+isStringJSONNumeric(str)
+```
+
+`isStringJSONNumeric` reports whether string `s` is a number as defined by [JSON](https://www.json.org/json-en.html).
+
 ### fn isStringNumeric
 
 ```ts

test/ascii_test.jsonnet

@@ -42,3 +42,51 @@ test.new(std.thisFile)
     expected=true,
   )
 )
+
++ std.foldl(
+  function(acc, str)
+    acc
+    + test.case.new(
+      name='valid: ' + str,
+      test=test.expect.eq(
+        actual=ascii.isStringJSONNumeric(str),
+        expected=true,
+      )
+    ),
+  [
+    '15',
+    '1.5',
+    '-1.5',
+    '1e5',
+    '1E5',
+    '1.5e5',
+    '1.5E5',
+    '1.5e-5',
+    '1.5E+5',
+  ],
+  {},
+)
++ std.foldl(
+  function(acc, str)
+    acc
+    + test.case.new(
+      name='invalid: ' + str,
+      test=test.expect.eq(
+        actual=ascii.isStringJSONNumeric(str),
+        expected=false,
+      )
+    ),
+  [
+    '15e',
+    '1.',
+    '+',
+    '+1E5',
+    '.5',
+    'E5',
+    'e5',
+    '15e5garbage',
+    '1garbag5e5garbage',
+    'garbage15e5garbage',
+  ],
+  {},
+)